SUMIF 関数

SUMIF 関数

Excel for Microsoft 365 Excel for Microsoft 365 for Mac Excel for the web Excel 2021 Excel 2021 for Mac Excel 2019 Excel 2019 for Mac Excel 2016 その他…表示数を減らす

指定した条件を満たす範囲内の値を合計するには、SUMIF 関数を使用します。たとえば、数値を含む列で、5 より大きい値のみを合計するとします。次の数式を使用できます: =SUMIF(B2:B25," >5")

このビデオは、「 target=”_blank” title=”Excel で数値を追加する」” rel=”noopener”>Excel で数値を追加する」というトレーニングコースの一部です。

ヒント:

必要に応じて、任意の範囲に条件を適用し、別の範囲にある対応値を合計することもできます。たとえば、数式 =SUMIF(B2:B5, "John", C2:C5) は、C2:C5 の範囲で、対応する B2:B5 の範囲のセルが "John" の値のみを合計します。
複数の条件に基づいてセルを合計する場合は、「 target=”_blank” title=”SUMIFS 関数” rel=”noopener”>SUMIFS 関数」を参照してください。

重要: SUMIF 関数は、255 文字を超える文字列または文字列 #VALUE! と一致させるために使用すると、正しくない結果を返します。

構文

SUMIF(範囲, 検索条件, [合計範囲])

SUMIF 関数の書式には、次の引数があります。

範囲必ず指定します。条件によって評価するセルの範囲。各範囲のセルには、数値または名前、配列、または数値を含む参照を指定する必要があります。空の値とテキスト値は無視されます。選択した範囲には、標準の Excel 形式の日付が含まれる場合があります (下の例)。
条件必ず指定します。数値、式、セル参照、テキスト、または追加するセルを定義する関数の形式の条件。ワイルドカード文字を含めることができます。疑問符 (?) は任意の 1 文字に一致し、アスタリスク () は任意の文字シーケンスに一致します。ワイルドカード文字ではなく、通常の文字として疑問符やアスタリスクを検索する場合は、その文字の前に、"~" のように半角のチルダ (~) を付けます。

たとえば、条件は 32、">32"、B5、"3?"、"apple"、"~?"、または TODAY() として表すことができます。

重要: 文字列条件や、論理記号または数学記号を含む条件は、二重引用符 (") で囲む必要があります。条件が数値の場合、二重引用符は不要です。

sum_range 省略可能です。 range 引数で指定されたセル以外のセルを追加する場合は、追加する実際のセル。 sum_range 引数を省略すると、** 範囲引数で** 指定されたセル (条件が適用されるセルと同じセル) が追加されます。

Sum_range ** は、 **範囲と同じサイズと形状にする必要があります。そうでない場合、パフォーマンスが低下する可能性があり、数式は、 sum_range の最初のセルで始まるが、範囲と同じ次元を持つセル の範囲 を合計します。次に例を示します。

範囲	**sum_range **	実際の合計セル
A1:A5	B1:B5	B1:B5
A1:A5	B1:K5	B1:B5

使用例

使用例 1

次の表のサンプルデータをコピーし、新しい Excel ワークシートのセル A1 に貼り付けます。数式を選択して、F2 キーを押し、さらに Enter キーを押すと、結果が表示されます。必要に応じて、列幅を調整してすべてのデータを表示してください。

資産価格	手数料	データ
¥10,000,000	¥700,000	¥25,000,000
¥20,000,000	¥1,400,000
¥30,000,000	¥2,100,000
¥40,000,000	¥2,800,000
数式	説明	結果
=SUMIF(A2:A5,">16000000",B2:B5)	価格が ¥ 16,000,000 を超えるエアコンに対しての取り付け手数料の合計を計算します。	¥6,300,000
=SUMIF(A2:A5,">16000000")	¥ 16,000,000 を超えるエアコン価格の合計を計算します。	¥90,000,000
=SUMIF(A2:A5,30000000,B2:B5)	価格が ¥ 30,000,000 であるエアコンに対しての取り付け手数料の合計を計算します。	¥2,100,000
=SUMIF(A2:A5,">" & C2,B2:B5)	価格が C2 の値を超えるエアコンに対しての取り付け手数料の合計を計算します。	¥4,900,000

使用例 2

カテゴリ	食材	売上
野菜	トマト – 箱	¥230,000
野菜	セロリ	¥550,000
くだもの	オレンジ – 箱	¥80,000
	バター	¥40,000
野菜	ニンジン	¥420,000
くだもの	リンゴ – 箱	¥120,000
数式	説明	結果
=SUMIF(A2:A7,"くだもの",C2:C7)	"くだもの" カテゴリのすべての食品の売上合計を計算します。	$200,000
=SUMIF(A2:A7,"野菜",C2:C7)	"野菜" カテゴリのすべての食品の売上合計を計算します。	¥1,200,000
=SUMIF(B2:B7,"*箱",C2:C7)	"箱" で終わるすべての食品 (トマト – 箱、オレンジ – 箱、およびリンゴ – 箱) の売上合計を計算します。	¥430,000
=SUMIF(A2:A7,"",C2:C7)	カテゴリが指定されていない食品すべての売上合計を計算します。	¥40,000

ページの先頭へ

構文

使用例

使用例 1

使用例 2

関連項目